home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / dsp / dr.bub / 96000.lha / 96000 / appb / b144.asm < prev    next >
Assembly Source File  |  1992-04-28  |  54KB  |  1,062 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.44    Wire-Frame Graphics Rendering  
  8. ;         WIRE-FRAME RENDITION OF A THREE DIMENSIONAL POLYLINE 
  9. ;                     ON THE MOTOROLA DSP96002  
  10. ;                         Version 1.00 
  11. ;
  12. ;OVERVIEW  
  13. ;This program displays a three dimensional polyline in two dimensions.  The points of the polyline, as 
  14. ;defined in the input list, are  projected into two dimensions using the perspective transformation.  
  15. ;The projected points are output to a display list that can be drawn  by a graphics engine or a fast 
  16. ;drawing program.  
  17. ;In order to maximize speed, two loops perform the graphics  transformations:  the trivial accept loop 
  18. ;and the trivial reject loop.  
  19. ;The trivial accept loop assumes that the last displayed point was  inside the viewing pyramid and thus 
  20. ;not clipped.  It pulls a new  point from the input list, converts it to clipping space and checks  if it is 
  21. ;inside the viewing pyramid.  If so, the routine performs  the perspective transformation, scales and 
  22. ;translates the point so  it lies within the viewing window, and finally adds it to the  display list.  
  23. ;If the point is found to lie outside the viewing pyramid, an  algorithm to clip a single point is per-
  24. ;formed and the program  enters the trivial reject loop.  
  25. ;The trivial reject loop assumes that the last displayed point was  outside the viewing pyramid.  It pulls 
  26. ;a new point from the input  list, converts it to clipping space and checks if the line joining  the new 
  27. ;point and the last point can be trivially rejected.  Trivial rejection occurs when both points of a line lie 
  28. ;outside of  a clipping plane.  When this occurs, the current point is saved  and the trivial reject loop 
  29. ;repeats.  
  30. ;Should the line not be trivially rejected but the current point  is accepted, an algorithm to clip a single 
  31. ;point is performed.  If  the current point is not accepted,  two-point clipping is  performed.  
  32. ;PERFORMANCE  
  33. ;All times are given in instruction cycles.  
  34. ;  Accept loop 
  35. ;    First point                       38 
  36. ;    Each additional point             39 
  37. ; 
  38. ;  Accept single point clip 
  39. ;    Minimum (single plane)            68 
  40. ;    Maximum (three planes)            94 
  41. ; 
  42. ;  Reject loop 
  43. ;    Each point                        37 
  44. ; 
  45. ;  Reject single point clip 
  46. ;    Minimum (single plane)            89 
  47. ;    Maximum (three planes)           115 
  48. ; 
  49. ;  Reject double clip line drawn 
  50. ;    Minimum (two single planes)      145 
  51. ;    Maximum (six planes)             206 
  52. ; 
  53. ;  Reject double clip line rejected 
  54. ;    Minimum (two single planes)      112 
  55. ;    Maximum (six planes)             173 
  56. ;
  57. ;The DSP96002 has an instruction cycle time of 74ns and will  transform 347K points/sec in the ac-
  58. ;cept loop.  In the reject loop,  365K points can be rejected each second.  
  59. ;INPUT  
  60. ;Before calling the polyline generator, address register r1 should  point to the area in X memory which 
  61. ;contains the X, Y and Z  coordinates of the input points.  Data register d7.l should  contain the num-
  62. ;ber of points in the polyline in the form of a  32-bit integer.  
  63. ;OUTPUT  
  64. ;Address register r5 should point to a display list data area when  the polyline generator is called.  Af-
  65. ;terwards, the display list will  be in the following format:  
  66. ;  Polygon1:  X1,Y1 
  67. ;             X2,Y2 
  68. ;             X3,Y3 
  69. ;                                       Xn,Yn 
  70. ; 
  71. ;  Delimiter  -1.0 
  72. ; 
  73. ;  Polygon2:  X1,Y1 
  74. ;             X2,Y2 
  75. ;                            Delimiter  -1.0 
  76. ;            PolygonM:  X1,Y1 
  77. ;              
  78. ;             Xn,Yn 
  79. ;             -2.0 
  80. ;
  81. ;All coordinates are in IEEE single-precision floating-point format to  speed up the DSP96002 float-
  82. ;ing-point incremental line drawing algorithm.  
  83. ;ADDRESS REGISTER USAGE  
  84. ;Four address registers are used:  
  85. ;  r0    input list 
  86. ;  r1    temporary coordinates 
  87. ;  r4    transformation matrix, scale and offset for 2D transformation 
  88. ;  r5    output list 
  89. ;  r6    miscellaneous scratchpad memory 
  90. ;
  91. ;The following memory map results:  
  92. ;                X Memory     Y Memory 
  93. ; 
  94. ;          r0   ?    Xobj0 
  95. ;          n0=0.0 Yobj0 
  96. ;                 Zobj0 
  97. ;                 Xobj1 
  98. ;                                     
  99. ;          r1 ?    Xnew         Znew 
  100. ;          n1=2   Ynew         Wnew 
  101. ;          m1=3   Xold         Zold 
  102. ;                 Yold         Wold 
  103. ; 
  104. ;          r4 ?                    Matrix1,1 
  105. ;          n4=2   Matrix4,1    Matrix2,1 
  106. ;          m4=13               Matrix3,1 
  107. ;                              Matrix1,2 
  108. ;                 Matrix4,2    Matrix2,2 
  109. ;                              Matrix3,2 
  110. ;                              Matrix1,3 
  111. ;                 Matrix4,3    Matrix2,3 
  112. ;                              Matrix3,3 
  113. ;                              Matrix1,4 
  114. ;                 Matrix4,4    Matrix2,4 
  115. ;                              Matrix3,4 
  116. ;                 Xscale       Xoffset 
  117. ;                 Yscale       Yoffset 
  118. ; 
  119. ;                              Xout0   ?  r5 
  120. ;                              Yout0     n5=-1.0 
  121. ;                              Xout1 
  122. ;                              Yout1 
  123. ;                                                             
  124. ;                 TempCount    TOld,Xtemp ? r6  (temporaries) 
  125. ;                              Ytemp 
  126. ;                              Wtemp 
  127. ;
  128. ;Several registers hold constants that speed up calculations.  These are:  
  129. ;  d8 =  1.0 for double point clipping 
  130. ;  d9 =  2.0 for division 
  131. ;  n0 =  0.0 for z limit test and double point clipping 
  132. ;  n5 = -1.0 for end of polyline marker 
  133. ;
  134. ;TRIVIAL ACCEPT LOOP  
  135. ;The transformation from object space to screen space is performed  in lines 19-33.  This is a 
  136. ;{1x4}{4x4} matrix multiplication but  because the W coordinate of the {1x4} input vector {X Y Z W} is  
  137. ;always equal to one, four multiplications can be eliminated.  
  138. ;Lines 39-47 determine if the point is within the viewing pyramid.  The FCMP s,d instruction is de-
  139. ;signed to clear the sticky accept  (A) bit (bit 7 in the CCR) whenever s > d.  By switching the order  
  140. ;of the operands, the FCMP instruction can be used to test both the  maximum and minimum bound-
  141. ;aries of a window.  To test acceptance,  the A bit is set in line 40 and the X and Y coordinates are  
  142. ;compared to the boundaries -W and W.  The Z coordinate is compared  to the boundaries 0 and W.  
  143. ;If the A bit remains set, the point is  within the viewing pyramid and is transformed to screen  coordi-
  144. ;nates.  
  145. ;If the A bit is clear, the reject loop is entered.  Note that the  A bit is only affected by the CMP, 
  146. ;CMPG, FCMP and FCMPG instructions.  
  147. ;The reciprocal 1/W is calculated in lines 53-58.  The result is  accurate to approximately 32 bits.  It is 
  148. ;multiplied by the X  coordinate and then by the X scale to scale the data to the output  screen.  The 
  149. ;coordinate is then translated to screen space.  The  procedure is repeated for the Y coordinate and 
  150. ;the coordinates  are added to the display list.  
  151. ;For additional points the accept loop code is almost identical to  the first point code except that if 
  152. ;the new point is not within  the viewing pyramid, a jump to a single point clipping routine is  per-
  153. ;formed.  
  154. ;ACCEPT LOOP SINGLE POINT CLIPPING CODE  
  155. ;The method used for clipping a line when one point is inside the  viewing pyramid and one point is 
  156. ;outside is a special case of a  general clipping algorithm presented in [1] and is used in the  double 
  157. ;point clipping code.  
  158. ;Suppose that the line between points P1 and P2 was rejected because  the x coordinate of P2, x2, 
  159. ;was larger than w2.  Then,  
  160. ;  y2 = y1 + t (y2 - y1) 
  161. ; 
  162. ;where 
  163. ; 
  164. ;  t  =         w1 - x1 
  165. ;        --------------------- 
  166. ;        (w1 - x1) - (w2 - x2) 
  167. ; 
  168. ;Substituting the value of t results in the determinant 
  169. ; 
  170. ;  y2 =   | y2  w2-y2 | 
  171. ;         | y1  w1-y1 | 
  172. ;      ------------------- 
  173. ;       (w1-x1) - (w2-x2) 
  174. ;
  175. ;The equations for z2 and w2 are analogous.  Since w2 has the same  denominator as x2, y2 and z2, 
  176. ;and these will be divided by w2 in the  perspective transformation, the division shown above does 
  177. ;not need  to be performed.  
  178. ;Lines 151-162 determine which planes that the point is outside and  call the appropriate clipping rou-
  179. ;tines.  These routines (lines 520-617)  calculate the determinants and return with the resulting coordi-
  180. ;nates in  the data registers.  
  181. ;The resulting point is transformed using the perspective  transformation, scaled and translated in 
  182. ;lines 168-186.  A code (-1.0)  is stored in the display list to indicate that the next line to be  drawn is 
  183. ;not joined with the current one.  Control is then transferred  to the trivial reject loop.  
  184. ;TRIVIAL REJECT LOOP  
  185. ;The trivial reject loop starts with the {1x4}{4x4} matrix  multiplication to transform the input point to 
  186. ;clipping space.  Next,  the line joining the current point and the previously rejected  point is tested 
  187. ;for trivial rejection.  As mentioned earlier,  trivial rejection occurs whenever both of the endpoints lie 
  188. ;outside  of one clipping plane.  
  189. ;A sticky bit called Local Reject (LR) is defined as bit 5 of the  CCR.  It is cleared by the FCMP s,d in-
  190. ;struction whenever s <= d.  In other words, the LR bit is cleared whenever the FCMP instruction  
  191. ;finds the coordinate inside of the boundary.  
  192. ;An additional instruction, FCMPG, is needed because trivial  rejection occurs when both points are 
  193. ;outside of any boundary  plane.  Thus, an additional sticky bit called Reject (R) (bit 6 of  the CCR) is 
  194. ;used to "remember" that a trivial reject has occurred  after comparisons against one boundary plane.  
  195. ;The FCMPG  instruction affects R and is performed as the last comparison to a  boundary plane.  
  196. ;When FCMPG s,d is executed, the R flag is cleared  if the previous point was outside of the bound-
  197. ;ary (LR is set) and  the current point is outside of the boundary (s > d).  The FCMPG  instruction al-
  198. ;so resets the LR bit to 1 for comparison to the next  boundary plane.  
  199. ;To perform the trivial reject test, the LR and R bits are set to 1.  The two points are tested against 
  200. ;the X = -W boundary plane and  then tested against the X = W plane etc.  The first point is tested  us-
  201. ;ing FCMP and the second point is tested using FCMPG to clear the  R bit if both comparisons were 
  202. ;outside of the boundary.  At the end  of these comparisons, if the R bit is 0, the line was trivially  re-
  203. ;jected.  With this definition, the trivial rejection test can be  generalized to a polygon with any number 
  204. ;of points.  The execution  time is of order 6N cycles where N is the number of points.  
  205. ;The lines 225-236 perform the trivial reject test.  Should the line  be trivially rejected, the new coordi-
  206. ;nates are stored for the next  comparison and the reject loop repeats.  
  207. ;If the line is not trivially rejected, a check is made to determine  if the current point is accepted.  If so, 
  208. ;control is transferred to  the reject loop single point clip routine.  Otherwise the double  point routine 
  209. ;is entered.  
  210. ;REJECT LOOP SINGLE POINT CLIPPING CODE  
  211. ;The reject loop single point clipping code is very similar to the  analogous code in the accept loop.  It 
  212. ;calls the same clipping  subroutines in lines 520-617.  Then the point that was just calculated  is trans-
  213. ;formed, scaled and translated and stored in the output list  (lines 305-321).  Finally, the new point 
  214. ;(which was accepted) is  transformed, scaled and translated (lines 327-345).  Control is  transferred 
  215. ;to the accept loop.  
  216. ;REJECT LOOP DOUBLE POINT CLIPPING CODE  
  217. ;Lines 359-492 are a direct implementation of a clipping algorithm  using endpoint coordinates given 
  218. ;in {1}.  The clipping method using  determinants is not powerful enough to handle the cases where 
  219. ;the  line is rejected but not trivially rejected.  Thus, the line  parameters t1 and t2 are calculated explic-
  220. ;itly.  The t1 parameter  is calculated based on the coordinates of the old point and the  t2 parameter 
  221. ;is calculated based on the current point.  
  222. ;These parameters are calculated by a set of double point clipping  subroutines in lines 631-853.  These 
  223. ;subroutines are called based  on the coordinates in lines 359-395.  
  224. ;The line is checked for rejection which occurs when t1 > t2.  If  the line is not rejected, the plane inter-
  225. ;sections are interpolated  based on t1 and t2 (lines 409-431).  Then the two new points are  trans-
  226. ;formed, scaled and translated in lines 437-478.  Control is  then transferred to the reject loop.  
  227. ;If the line is rejected, control is transferred to the reject loop  after some housekeeping is performed.  
  228. ;TERMINATION CODE  
  229. ;Lines 499-509 swallow the line delimiter code (-1.0) if it is the  last coordinate in the display list.  
  230. ;Then it adds the end of  display list code (-2.0) to the display list and exits.  
  231. ;REFERENCE  
  232. ;{1}  William M. Newman and Robert F. Sproull, Principles of Interactive 
  233. ;     Computer Graphics, (New York:  McGraw-Hill, 1979). 
  234. ;
  235. ; 
  236. ;; WIRE-FRAME RENDITION OF A THREE DIMENSIONAL POLYLINE 
  237. ;               ON THE MOTOROLA DSP96002 
  238. ; 
  239. ;           Version 1.00  18-Nov-88   
  240. ; 
  241. ; 
  242. ; 
  243. ;--------------------------------------------------------- 
  244. ; 
  245. ;                     First point 
  246. ; 
  247. ;--------------------------------------------------------- 
  248.  
  249.  
  250. ; Transform to clip space 
  251. ;                                                                 Words     ICycles
  252. wf3d 
  253.   move                         x:(r0)+,d0.s                ;X       1  1 
  254.   move                         x:(r0)+,d5.s   y:(r4)+,d4.s ;Y   M11 1  1 
  255.   fmpy.s d4,d0,d2              x:(r4)+,d3.s   y:,d4.s      ;M41 M21 1  1 
  256.   fmpy   d4,d5,d3 fadd.s d3,d2 x:(r0)+,d6.s   y:(r4)+,d4.s ;Z   M31 1  1 
  257.   fmpy   d4,d6,d3 fadd.s d3,d2 x:(r1)+n1,d1.s y:(r4)+,d4.s ;r1+ M12 1  1 
  258.   fmpy   d4,d0,d1 fadd.s d3,d2 x:(r4)+,d3.s   y:,d4.s      ;M42,M22 1  1 
  259.   fmpy   d4,d5,d3 fadd.s d3,d1                y:(r4)+,d4.s ;    M32 1  1 
  260.   fmpy   d4,d6,d3 fadd.s d3,d1 d2.s,x:(r1)+   y:(r4)+,d4.s ;Xo  M13 1  1 
  261.   fmpy   d4,d0,d2 fadd.s d3,d1 x:(r4)+,d3.s   y:,d4.s      ;M43 M23 1  1 
  262.   fmpy   d4,d5,d3 fadd.s d3,d2                y:(r4)+,d4.s ;    M33 1  1 
  263.   fmpy   d4,d6,d3 fadd.s d3,d2 d1.s,x:(r1)-   y:(r4)+,d4.s ;Yo  M14 1  1 
  264.   fmpy   d4,d0,d1 fadd.s d3,d2 x:(r4)+,d3.s   y:,d4.s      ;M44 M24 1  1 
  265.   fmpy   d4,d5,d3 fadd.s d3,d1                y:(r4)+,d4.s ;    M34 1  1 
  266.   fmpy   d4,d6,d3 fadd.s d3,d1                d2.s,y:(r1)  ;    Zo  1  1 
  267.                   fadd.s d3,d1 x:(r1)+,d0.s                ;Xo      1  1 
  268.  
  269.  
  270. ; Test if point is within viewing pyramid 
  271.  
  272.   fneg.s d1                    d1.s,d2.s                   ;        1  1 
  273.   ori    #$80,ccr                                          ;        1  1 
  274.   fcmp   d1,d0                                             ;        1  1 
  275.   fcmp   d0,d2                 x:(r1)-,d5.s                ;Yo      1  1 
  276.   fcmp   d1,d5                 n0,d4.s                     ;        1  1 
  277.   fcmp   d5,d2                                y:(r1)+,d6.s ;    Zo  1  1 
  278.   fcmp   d4,d6                                             ;        1  1 
  279.   fcmp   d6,d2                                             ;        1  1 
  280.   jclr   #7,sr,_reject_entry                               ;        2  3 
  281.  
  282.  
  283. ; Calculate reciprocal 1/W 
  284.  
  285.  
  286.   fseedd d2,d6                                             ;        1  1 
  287.   fmpy.s d2,d6,d1              d9.s,d4.s                   ;        1  1 
  288.                   fsub.s d1,d4 d4.s,d3.s      d2.s,y:(r1)+ ;    Wo  1  1 
  289.   fmpy.s d1,d4,d1                                          ;        1  1 
  290.   fmpy   d6,d4,d1 fsub.s d1,d3                             ;        1  1 
  291.   fmpy.s d1,d3,d1              x:(r4)+,d4.s   y:,d3.s      ;Xs  Xf  1  1 
  292.  
  293.  
  294. ; Multiply coordinates by 1/W, scale and add offset 
  295.  
  296.  
  297.   fmpy.s d0,d4,d2                                          ;        1  1 
  298.   fmpy.s d2,d1,d2              x:(r4)+,d4.s   y:,d6.s      ;Ys  Yf  1  1 
  299.   fmpy   d5,d4,d3 fadd.s d3,d2                             ;        1  1 
  300.   fmpy.s d3,d1,d3                             d2.s,y:(r5)+ ;        1  1 
  301.                   fadd.s d6,d3 x:(r0)+,d0.s                ;        1  1 
  302.   dec    d7                                   d3.s,y:(r5)+ ;    Y1  1  1 
  303.  
  304.  
  305.  
  306.  
  307. ;--------------------------------------------------------- 
  308. ; 
  309. ;                    Accept loop 
  310. ; 
  311. ;--------------------------------------------------------- 
  312.  
  313.  
  314. ; Transform point to clip space 
  315.  
  316.  
  317. _accept_loop 
  318.   move                         x:(r0)+,d5.s   y:(r4)+,d4.s ;Y   M11 1  1 
  319.   fmpy.s d4,d0,d2              x:(r4)+,d3.s   y:,d4.s      ;M41 M21 1  1 
  320.   fmpy   d4,d5,d3 fadd.s d3,d2 x:(r0)+,d6.s   y:(r4)+,d4.s ;Z   M31 1  1 
  321.   fmpy   d4,d6,d3 fadd.s d3,d2                y:(r4)+,d4.s ;    M12 1  1 
  322.   fmpy   d4,d0,d1 fadd.s d3,d2 x:(r4)+,d3.s   y:,d4.s      ;M42,M22 1  1 
  323.   fmpy   d4,d5,d3 fadd.s d3,d1                y:(r4)+,d4.s ;    M32 1  1 
  324.   fmpy   d4,d6,d3 fadd.s d3,d1 d2.s,x:(r1)+   y:(r4)+,d4.s ;Xn  M13 1  1 
  325.   fmpy   d4,d0,d2 fadd.s d3,d1 x:(r4)+,d3.s   y:,d4.s      ;M43 M23 1  1 
  326.   fmpy   d4,d5,d3 fadd.s d3,d2                y:(r4)+,d4.s ;    M33 1  1 
  327.   fmpy   d4,d6,d3 fadd.s d3,d2 d1.s,x:(r1)-   y:(r4)+,d4.s ;Yn  M14 1  1 
  328.   fmpy   d4,d0,d1 fadd.s d3,d2 x:(r4)+,d3.s   y:,d4.s      ;M44 M24 1  1 
  329.   fmpy   d4,d5,d3 fadd.s d3,d1                y:(r4)+,d4.s ;    M34 1  1 
  330.   fmpy   d4,d6,d3 fadd.s d3,d1                d2.s,y:(r1)  ;    Zn  1  1 
  331.                   fadd.s d3,d1 x:(r1)+,d0.s                ;Xn      1  1 
  332.  
  333.  
  334.  
  335. ; Determine if point is within view volume 
  336.  
  337.  
  338.   fneg.s d1                    d1.s,d2.s                   ;        1  1 
  339.   ori    #$80,ccr                                          ;        1  1 
  340.   fcmp   d1,d0                                d2.s,y:(r1)  ;    Wn  1  1 
  341.   fcmp   d0,d2                 x:(r1)-,d5.s                ;Yn      1  1 
  342.   fcmp   d1,d5                 n0,d4.s                     ;        1  1 
  343.   fcmp   d5,d2                                y:(r1)-,d6.s ;    Zn  1  1 
  344.   fcmp   d4,d6                 d7.l,x:(r6)                 ;        1  1 
  345.   fcmp   d6,d2                 d6.s,d7.s                   ;        1  1 
  346.   jclr   #7,sr,_accept_clip                                ;        2  3 
  347.  
  348.  
  349. ; Calculate reciprocal 1/W 
  350.  
  351.  
  352.   fseedd d2,d6                                             ;        1  1 
  353.   fmpy.s d2,d6,d1              d9.s,d4.s                   ;        1  1 
  354.                   fsub.s d1,d4 d4.s,d3.s      d2.s,y:(r1)- ;    Wo  1  1 
  355.   fmpy.s d1,d4,d1              d0.s,x:(r1)+   d7.s,y:      ;Xo  Zo  1  1 
  356.   fmpy   d6,d4,d1 fsub.s d1,d3 d5.s,x:(r1)+                ;Yo      1  1 
  357.   fmpy.s d1,d3,d1              x:(r4)+,d4.s   y:,d3.s      ;Xs  Xf  1  1 
  358.  
  359.  
  360. ; Multiply coordinates by 1/W, scale and add offset 
  361.  
  362.  
  363.   fmpy.s d0,d4,d2                                          ;        1  1 
  364.   fmpy.s d2,d1,d2              x:(r4)+,d4.s   y:,d6.s      ;Ys  Yf  1  1 
  365.   fmpy   d5,d4,d3 fadd.s d3,d2 x:(r6),d7.l                 ;        1  1 
  366.   fmpy.s d3,d1,d3                             d2.s,y:(r5)+ ;        1  1 
  367.                   fadd.s d6,d3 x:(r0)+,d0.s                ;        1  1 
  368.   dec    d7                                   d3.s,y:(r5)+ ;    Y1  1  1 
  369.   jne    _accept_loop                                      ;        2  2 
  370.   jmp    _end                                              ;        2  2 
  371.  
  372.  
  373. ;--------------------------------------------------------- 
  374. ; 
  375. ;            Accept loop single-clip routine 
  376. ; 
  377. ;--------------------------------------------------------- 
  378.  
  379.  
  380. ; Dispatch to single-plane clipping routines 
  381.  
  382.  
  383. _accept_clip 
  384.   fsub.s d0,d2                 d2.s,d1.s                   ;        1  1 
  385.   fjslt  _clip1_xp                                         ;        2  2 
  386.   fadd.s d0,d1                 d1.s,d2.s                   ;        1  1 
  387.   fjslt  _clip1_xn                                         ;        2  2 
  388.   fsub.s d5,d2                 d2.s,d1.s                   ;        1  1 
  389.   fjslt  _clip1_yp                                         ;        2  2 
  390.   fadd.s d5,d1                 d1.s,d2.s                   ;        1  1 
  391.   fjslt  _clip1_yn                                         ;        2  2 
  392.   fsub.s d6,d2                 d2.s,d1.s                   ;        1  1 
  393.   fjslt  _clip1_zp                                         ;        2  2 
  394.   ftst   d6                                                ;        1  1 
  395.   fjslt  _clip1_zn                                         ;        2  2 
  396.  
  397.  
  398. ; Calculate reciprocal 1/W 
  399.  
  400.  
  401.   fseedd d1,d6                                             ;        1  1 
  402.   fmpy.s d1,d6,d1              d9.s,d4.s                   ;        1  1 
  403.                   fsub.s d1,d4 d4.s,d3.s      y:(r1)+n1,d2.s ; r1+2 1  1 
  404.   fmpy.s d1,d4,d1              x:(r1)+n1,d2.s y:,d7.s      ;Yn  Wn  1  1 
  405.   fmpy   d6,d4,d1 fsub.s d1,d3 d2.s,x:(r1)+   d7.s,y:      ;Yo  Wo  1  1 
  406.   fmpy.s d1,d3,d1              x:(r4)+,d4.s   y:,d3.s      ;Xs  Xf  1  1 
  407.  
  408.  
  409. ; Multiply coordinates by 1/W, scale and add offset 
  410.  
  411.   fmpy.s d0,d4,d2              x:(r1)+n1,d0.s y:,d7.s      ;Xn  Zn  1  1 
  412.   fmpy.s d2,d1,d2              x:(r4)+,d4.s   y:,d6.s      ;Ys  Yf  1  1 
  413.   fmpy   d5,d4,d3 fadd.s d3,d2 d0.s,x:(r1)+n1 d7.s,y:      ;Xo  Zo  1  1 
  414.   fmpy.s d3,d1,d3              x:(r6),d7.l                 ;Cnt     1  1 
  415.                   fadd.s d6,d3 x:(r0)+,d0.s   d2.s,y:(r5)+ ;X       1  1 
  416.   move                                        d3.s,y:(r5)+ ;    Y1  1  1 
  417.   dec    d7                                   n5,y:(r5)+   ;   -1.0 1  1 
  418.   jne    _reject_loop                                      ;        2  2 
  419.   jmp    _end                                              ;        2  2 
  420.  
  421. ;--------------------------------------------------------- 
  422. ; 
  423. ;                    Reject loop 
  424. ; 
  425. ;--------------------------------------------------------- 
  426.  
  427.  
  428. ; Transform point to clip space 
  429.  
  430. _reject_entry 
  431.   dec    d7                                   d2.s,y:(r1)+ ;    Wo  1  1 
  432.   move                         x:(r0)+,d0.s  y:(r4)+n4,d4.s ;X r4+2 1  1 
  433.  
  434. _reject_loop 
  435.   move                         x:(r0)+,d5.s  y:(r4)+,d4.s  ;Y   M11 1  1 
  436.   fmpy.s d4,d0,d2              x:(r4)+,d3.s  y:,d4.s       ;M41 M21 1  1 
  437.   fmpy   d4,d5,d3 fadd.s d3,d2 x:(r0)+,d6.s  y:(r4)+,d4.s  ;    M31 1  1 
  438.   fmpy   d4,d6,d3 fadd.s d3,d2               y:(r4)+,d4.s  ;    M12 1  1 
  439.   fmpy   d4,d0,d1 fadd.s d3,d2 x:(r4)+,d3.s  y:,d4.s       ;M42 M22 1  1 
  440.   fmpy   d4,d5,d3 fadd.s d3,d1               y:(r4)+,d4.s  ;    M32 1  1 
  441.   fmpy   d4,d6,d3 fadd.s d3,d1 d2.s,x:(r1)+  y:(r4)+,d4.s  ;Xn  M13 1  1 
  442.   fmpy   d4,d0,d2 fadd.s d3,d1 x:(r4)+,d3.s  y:,d4.s       ;M43 M23 1  1 
  443.   fmpy   d4,d5,d3 fadd.s d3,d2               y:(r4)+,d4.s  ;    M33 1  1 
  444.   fmpy   d4,d6,d3 fadd.s d3,d2 d1.s,x:(r1)-  y:(r4)+,d4.s  ;Yn  M14 1  1 
  445.   fmpy   d4,d0,d1 fadd.s d3,d2 x:(r4)+,d3.s  y:,d4.s       ;M44 M24 1  1 
  446.   fmpy   d4,d5,d3 fadd.s d3,d1               y:(r4)+,d4.s  ;    M34 1  1 
  447.   fmpy   d4,d6,d3 fadd.s d3,d1               d2.s,y:(r1)-  ;    Zn  1  1 
  448.                   fadd.s d3,d1                             ;        1  1 
  449.  
  450.  
  451. ; Determine trivial rejection 
  452.  
  453.   ori    #$e0,ccr                                          ;        1  1 
  454.   fneg.s d1                    d1.s,d5.s      y:(r1)-,d2.s ;    Wo  1  1 
  455.   fneg.s d2                    x:(r1)+n1,d6.s d2.s,d4.s    ;Xo      1  1 
  456.   fcmp   d2,d6                 x:(r1)-,d0.s                ;Xn      1  1 
  457.   fcmpg  d1,d0                 (r4)+n4                     ;r4+2    1  1 
  458.   fcmp   d6,d4                                             ;        1  1 
  459.   fcmpg  d0,d5                 x:(r1)+n1,d6.s              ;Yo      1  1 
  460.   fcmp   d2,d6                 x:(r1)+,d3.s                ;Yn      1  1 
  461.   fcmpg  d1,d3                                             ;        1  1 
  462.   fcmp   d6,d4                                             ;        1  1 
  463.   fcmpg  d3,d5                              y:(r1)+n1,d6.s ;Zo      1  1 
  464.   fcmp   d6,d4                              y:(r1)+n1,d2.s ;Zn      1  1 
  465.   fcmpg  d2,d5                 n0,d4.s                     ;        1  1 
  466.   fcmp   d4,d6                                             ;        1  1 
  467.   fcmpg  d4,d2                                             ;        1  1 
  468.   jset   #6,sr,_reject_clip                                ;        2  3 
  469.  
  470. ; Save new point 
  471.  
  472.   move                         d0.s,x:(r1)+   d2.s,y:      ;Xo Zo   1  1 
  473.   move                         d3.s,x:(r1)+   d5.s,y:      ;Yo Wo   1  1 
  474.   dec    d7                    x:(r0)+,d0.s                ;X       1  1 
  475.   jne    _reject_loop                                      ;        2  2 
  476.   jmp    _end                                              ;        2  2 
  477.  
  478.  
  479. ;--------------------------------------------------------- 
  480. ; 
  481. ;             Reject loop clipping routine 
  482. ; 
  483. ;--------------------------------------------------------- 
  484.  
  485. ; Determine if new point is within view volume 
  486.  
  487. _reject_clip 
  488.   ori     #$80,ccr                                         ;        1  1 
  489.   fcmp    d1,d0                (r1)-                       ;r1-     1  1 
  490.   fcmp    d1,d3                               d5.s,y:(r1)+ ;    Wn  1  1 
  491.   fcmp    d4,d2                                            ;        1  1 
  492.   fcmp    d0,d5                                            ;        1  1 
  493.   fcmp    d3,d5                                            ;        1  1 
  494.   fcmp    d2,d5                                            ;        1  1 
  495.   jclr    #7,sr,_r_clip2                                   ;        2  3 
  496.  
  497.  
  498. ;--------------------------------------------------------- 
  499. ; 
  500. ;            Reject loop single-clip routine 
  501. ; 
  502. ;--------------------------------------------------------- 
  503.  
  504. ; Dispatch to clipping routines 
  505.  
  506.   move                         x:(r1)+,d0.s   y:,d6.s      ;Xo  Zo  1  1 
  507.   move                         x:(r1)+n1,d5.s y:,d2.s      ;Yo  Wo  1  1 
  508.   move                         d7.l,x:(r6)                 ;Cnt     1  1 
  509.   fsub.s d0,d2                 d2.s,d1.s                   ;        1  1 
  510.   fjslt  _clip1_xp                                         ;        2  2 
  511.   fadd.s d0,d1                 d1.s,d2.s                   ;        1  1 
  512.   fjslt  _clip1_xn                                         ;        2  2 
  513.   fsub.s d5,d2                 d2.s,d1.s                   ;        1  1 
  514.   fjslt  _clip1_yp                                         ;        2  2 
  515.   fadd.s d5,d1                 d1.s,d2.s                   ;        1  1 
  516.   fjslt  _clip1_yn                                         ;        2  2 
  517.   fsub.s d6,d2                 d2.s,d1.s                   ;        1  1 
  518.   fjslt  _clip1_zp                                         ;        2  2 
  519.   ftst   d6                                                ;        1  1 
  520.   fjslt  _clip1_zn                                         ;        2  2 
  521.  
  522. ; Calculate reciprocal 1/W (old point) 
  523.  
  524.  
  525.   fseedd d1,d6                                             ;        1  1 
  526.   fmpy.s d1,d6,d1              d9.s,d4.s                   ;        1  1 
  527.                   fsub.s d1,d4                d4.s,d3.s    ;        1  1 
  528.   fmpy.s d1,d4,d1                             (r4)-n4      ;   r4-2 1  1 
  529.   fmpy   d6,d4,d1 fsub.s d1,d3                             ;        1  1 
  530.   fmpy.s d1,d3,d1              x:(r4)+,d4.s   y:,d3.s      ;Xs  Xf  1  1 
  531.  
  532.  
  533. ; Multiply coordinates by 1/W, scale and add offset (old point) 
  534.  
  535.  
  536.   fmpy.s d0,d4,d2                                          ;        1  1 
  537.   fmpy.s d2,d1,d2              x:(r4)-,d4.s y:,d6.s        ;Ys  Yf  1  1 
  538.   fmpy   d5,d4,d3 fadd.s d3,d2                             ;        1  1 
  539.   fmpy.s d3,d1,d3                           d2.s,y:(r5)+   ;    X1  1  1 
  540.                   fadd.s d6,d3              y:(r1)+n1,d2.s ;    Wn  1  1 
  541.   move                                      d3.s,y:(r5)+   ;    Y1  1  1 
  542.  
  543.  
  544. ; Calculate reciprocal 1/W (new point) 
  545.  
  546.  
  547.   fseedd d2,d6                                             ;        1  1 
  548.   fmpy.s d2,d6,d1              d9.s,d4.s                   ;        1  1 
  549.                   fsub.s d1,d4 d4.s,d3.s      d2.s,y:(r1)+ ;    Wo  1  1 
  550.   fmpy.s d1,d4,d1              x:(r1)+n1,d0.s y:,d2.s      ;Xn  Zn  1  1 
  551.   fmpy   d6,d4,d1 fsub.s d1,d3 d0.s,x:(r1)-   d2.s,y:      ;Xo  Zo  1  1 
  552.   fmpy.s d1,d3,d1              x:(r4)+,d4.s   y:,d3.s      ;Xs  Xf  1  1 
  553.  
  554.  
  555. ; Multiply coordinates by 1/W, scale and add offset (new point) 
  556.  
  557.  
  558.   fmpy.s d0,d4,d2              x:(r1)+n1,d5.s              ;Yn      1  1 
  559.   fmpy.s d2,d1,d2              x:(r4)+,d4.s   y:,d6.s      ;Ys  Yf  1  1 
  560.   fmpy   d5,d4,d0 fadd.s d3,d2 d5.s,x:(r1)+                ;Yo      1  1 
  561.   fmpy.s d0,d1,d5              x:(r0)+,d0.s   d2.s,y:(r5)+ ;X   X1  1  1 
  562.                   fadd.s d5,d3 x:(r6),d7.l                 ;Cnt     1  1 
  563.   dec    d7                                   d3.s,y:(r5)+ ;    Y1  1  1 
  564.   jne    _accept_loop                                      ;        2  2 
  565.   jmp    _end                                              ;        2  2 
  566.  
  567.  
  568. ;--------------------------------------------------------- 
  569. ; 
  570. ;            Double point clipping routine 
  571. ; 
  572. ;--------------------------------------------------------- 
  573.  
  574.  
  575. ; Dispatch to old point clipping routines 
  576.  
  577.  
  578. _r_clip2 
  579.   move                         d7.l,x:(r6)    y:(r1)+,d1.l ;Cnt r1+ 1  1 
  580.   move                                        y:(r1)-,d1.s ;    Wo  1  1 
  581.   move                         x:(r1)+,d5.s                ;Xo      1  1 
  582.   move                         n0,d7.s                     ;        1  1 
  583.                   fsub.s d1,d5 d5.s,d6.s                   ;        1  1 
  584.   fjsgt  _clip2_xop                                        ;        2  2 
  585.                   fadd.s d1,d6 x:(r1)-,d5.s                ;Yo      1  1 
  586.   fjslt  _clip2_xon                                        ;        2  2 
  587.                   fsub.s d1,d5 d5.s,d6.s                   ;        1  1 
  588.   fjsgt  _clip2_yop                                        ;        2  2 
  589.                   fadd.s d1,d6              y:(r1)+n1,d5.s ;Zo      1  1 
  590.   fjslt  _clip2_yon                                        ;        2  2 
  591.                   fsub.s d1,d5 d5.s,d6.s                   ;        1  1 
  592.   fjsgt  _clip2_zop                                        ;        2  2 
  593.   ftst   d6                    x:(r1)+,d5.s                ;Xn      1  1 
  594.   fjslt  _clip2_zon                                        ;        2  2 
  595.   move                                      d7.s,y:(r6)    ;    to  1  1 
  596.  
  597.  
  598. ; Dispatch to new point clipping routines 
  599.  
  600.  
  601.   move                                      y:(r1),d1.s    ;    Wn  1  1 
  602.   move                         d8.s,d7.s                   ;    tn  1  1 
  603.                   fsub.s d1,d5 d5.s,d6.s                   ;        1  1 
  604.   fjsgt  _clip2_xnp                                        ;        2  2 
  605.                   fadd.s d1,d6 x:(r1)-,d5.s                ;Yn      1  1 
  606.   fjslt  _clip2_xnn                                        ;        2  2 
  607.                   fsub.s d1,d5 d5.s,d6.s                   ;        1  1 
  608.   fjsgt  _clip2_ynp                                        ;        2  2 
  609.                   fadd.s d1,d6              y:(r1)+n1,d5.s ;Zn      1  1 
  610.   fjslt  _clip2_ynn                                        ;        2  2 
  611.                   fsub.s d1,d5 d5.s,d6.s                   ;        1  1 
  612.   fjsgt  _clip2_znp                                        ;        2  2 
  613.   ftst   d6                                                ;        1  1 
  614.   fjslt  _clip2_znn                                        ;        2  2 
  615.  
  616. ; Check for rejection 
  617.  
  618.  
  619.   move                         x:(r1)+n1,d3.s y:(r6),d5.s  ;Xo  to  1  1 
  620.   fcmp   d5,d7                 d7.s,d4.s                   ;        1  1 
  621.   fjlt   _clip2_reject                                     ;        2  2 
  622.  
  623.  
  624. ; Calculate end point coordinates: X 
  625.  
  626.  
  627.   move                         x:(r1)+n1,d6.s              ;Xn      1  1 
  628.                   fsub.s d3,d6 d6.s,x:(r1)-                ;Xo      1  1 
  629.   fmpy.s d4,d6,d1                                          ;        1  1 
  630.   fmpy   d5,d6,d2 fadd.s d3,d1 x:(r1)+n1,d6.s              ;Yn      1  1 
  631.                   fadd.s d3,d2 x:(r1),d3.s                 ;Yo      1  1 
  632.  
  633.  
  634. ; Calculate end point coordinates: Y 
  635.  
  636.  
  637.                   fsub.s d3,d6 d6.s,x:(r1)+n1 d1.s,y:(r6)+ ;Yo  Xnd 1  1 
  638.   fmpy.s d4,d6,d1              d2.s,d0.s                   ;        1  1 
  639.   fmpy   d5,d6,d2 fadd.s d3,d1              y:(r1)+n1,d6.s ;    Wn  1  1 
  640.                   fadd.s d3,d2              y:(r1)+n1,d3.s ;    Wo  1  1 
  641.  
  642.  
  643. ; Calculate end point coordinates: W 
  644.  
  645.  
  646.                   fsub.s d3,d6              d1.s,y:(r6)+   ;Ynd     1  1 
  647.   fmpy.s d4,d6,d1              d2.s,d7.s    y:(r1)+n1,d4.s ;    Wn  1  1 
  648.   fmpy   d5,d6,d2 fadd.s d3,d1              d4.s,y:(r1)+   ;    Wo  1  1 
  649.                   fadd.s d3,d2              d1.s,y:(r6)    ;Wnd     1  1 
  650.  
  651.  
  652. ; Calculate reciprocal 1/W (old point) 
  653.  
  654.  
  655.   fseedd d2,d6                                             ;        1  1 
  656.   fmpy.s d2,d6,d1              d9.s,d4.s                   ;        1  1 
  657.                   fsub.s d1,d4 d4.s,d3.s                   ;        1  1 
  658.   fmpy.s d1,d4,d1                             (r4)-n4      ;   r4-2 1  1 
  659.   fmpy   d6,d4,d1 fsub.s d1,d3                             ;        1  1 
  660.   fmpy.s d1,d3,d1              x:(r4)+,d4.s   y:,d3.s      ;Xs  Xf  1  1 
  661.  
  662.  
  663.  
  664. ; Multiply coordinates by 1/W, scale and add offset (old point) 
  665.  
  666.  
  667.   fmpy.s d0,d4,d2                                          ;        1  1 
  668.   fmpy.s d2,d1,d2              x:(r4)-,d4.s y:,d6.s        ;Ys  Yf  1  1 
  669.   fmpy   d7,d4,d3 fadd.s d3,d2              y:(r1)+n1,d4.s ;    Zn  1  1 
  670.   fmpy.s d3,d1,d3                           d4.s,y:(r1)+n1 ;    Zo  1  1 
  671.                   fadd.s d6,d3              d2.s,y:(r5)+   ;    X1  1  1 
  672.   move                                      y:(r6)-,d1.s   ;    Wnd 1  1 
  673.   move                                      d3.s,y:(r5)+   ;    Y1  1  1 
  674.  
  675.  
  676. ; Calculate reciprocal 1/W (new point) 
  677.  
  678.  
  679.   fseedd d1,d6                                             ;        1  1 
  680.   fmpy.s d1,d6,d1              d9.s,d4.s                   ;        1  1 
  681.                   fsub.s d1,d4 d4.s,d3.s     y:(r6)-,d5.s  ;    Ynd 1  1 
  682.   fmpy.s d1,d4,d1                            y:(r6),d0.s   ;    Xnd 1  1 
  683.   fmpy   d6,d4,d1 fsub.s d1,d3                             ;        1  1 
  684.   fmpy.s d1,d3,d1              x:(r4)+,d4.s  y:,d3.s       ;Xs  Xf  1  1 
  685.  
  686.  
  687. ; Multiply coordinates by 1/W, scale and add offset (old point) 
  688.  
  689.  
  690.   fmpy.s d0,d4,d2                                          ;        1  1 
  691.   fmpy.s d2,d1,d2              x:(r4)+,d4.s   y:,d6.s      ;Ys  Yf  1  1 
  692.   fmpy   d5,d4,d3 fadd.s d3,d2                             ;        1  1 
  693.   fmpy.s d3,d1,d3              x:(r6),d7.l                 ;        1  1 
  694.                   fadd.s d6,d3 x:(r0)+,d0.s   d2.s,y:(r5)+ ;X   X1  1  1 
  695.   move                                        d3.s,y:(r5)+ ;    Y1  1  1 
  696.   dec    d7                                   n5,y:(r5)+   ;   -1.0 1  1 
  697.   jne    _reject_loop                                      ;        2  2 
  698.   jmp    _end                                              ;        2  2 
  699.  
  700.  
  701.  
  702. ; Reject double-clipped line 
  703.  
  704. _clip2_reject 
  705.   move                         x:(r6),d7.l                 ;        1  1 
  706.   move                         x:(r1)+n1,d0.s y:,d1.s      ;Xn  Zn  1  1 
  707.   move                         d0.s,x:(r1)-   d1.s,y:      ;Xo  Zo  1  1 
  708.   move                         x:(r1)+n1,d0.s y:,d1.s      ;Yn  Wn  1  1 
  709.   move                         d0.s,x:(r1)+   d1.s,y:      ;Yo  Wo  1  1 
  710.   dec    d7                    x:(r0)+,d0.s                ;        1  1 
  711.   jne    _reject_loop                                      ;        2  2 
  712.  
  713.  
  714. ; Terminate endpoint list and exit 
  715.  
  716. _end 
  717.   move                         n5,d0.s                     ;-1.0    1  1 
  718.   move                         (r5)-                       ;        1  1 
  719.   move                                        y:(r5),d1.s  ;        1  1 
  720.   fcmp   d0,d1                                             ;        1  1 
  721.   fjeq  _end1                                              ;        2  2 
  722.   move                         (r5)+                       ;        1  1 
  723.  
  724. _end1 
  725.   move                         #-2.0,d0.s                  ;        2  2 
  726.   move                                        d0.s,y:(r5)+ ;        1  1 
  727.   rts                                                      ;        2  2 
  728.  
  729.  
  730. ;--------------------------------------------------------- 
  731. ; 
  732. ;            Single point clipping routines 
  733. ; 
  734. ;--------------------------------------------------------- 
  735.  
  736. ; x = w boundary 
  737.  
  738. _clip1_xp 
  739.   move                                        y:(r1)-,d4.s ;W1      1  1 
  740.   fmpy.s d2,d4,d3              x:(r1)+,d0.s   d2.s,d7.s    ;X1      1  1 
  741.                   fsub.s d0,d4 x:(r1)-,d0.s                ;Y1      1  1 
  742.   fmpy.s d1,d4,d1                                          ;        1  1 
  743.   fmpy   d4,d5,d2 fsub.s d3,d1 d0.s,d5.s                   ;        1  1 
  744.   fmpy.s d5,d7,d3                                          ;        1  1 
  745.   fmpy   d4,d6,d3 fsub.s d3,d2                y:(r1)+,d4.s ;Z1      1  1 
  746.   fmpy.s d4,d7,d2              d2.s,d5.s                   ;        1  1 
  747.                   fsub.s d2,d3 d1.s,d0.s                   ;        1  1 
  748.   move                         d3.s,d6.s                   ;        1  1 
  749.   rts                                                      ;        2  2 
  750.  
  751.  
  752. ; x = -w boundary 
  753.  
  754.  
  755. _clip1_xn 
  756.   move                                        y:(r1)-,d4.s ;W1      1  1 
  757.   fmpy.s d1,d4,d3              x:(r1)+,d0.s   d1.s,d7.s    ;X1      1  1 
  758.                   fadd.s d0,d4 x:(r1)-,d0.s                ;Y1      1  1 
  759.   fmpy.s d2,d4,d2                                          ;        1  1 
  760.   fmpy   d4,d5,d1 fsub.s d3,d2 d0.s,d5.s                   ;        1  1 
  761.   fmpy.s d5,d7,d3                                          ;        1  1 
  762.   fmpy   d4,d6,d3 fsub.s d3,d1                y:(r1)+,d4.s ;Z1      1  1 
  763.   fmpy.s d4,d7,d1              d1.s,d5.s                   ;        1  1 
  764.                   fsub.s d1,d3 d2.s,d0.s                   ;        1  1 
  765.   fneg.s d0                    d3.s,d6.s                   ;        1  1 
  766.   rts                                                      ;        2  2 
  767.  
  768.  
  769. ; y = w boundary 
  770.  
  771.  
  772. _clip1_yp 
  773.   move                                        y:(r1),d4.s  ;W1      1  1 
  774.   fmpy.s d2,d4,d3              x:(r1)-,d5.s   d2.s,d7.s    ;Y1      1  1 
  775.                   fsub.s d5,d4 x:(r1),d5.s                 ;X1      1  1 
  776.   fmpy.s d1,d4,d1                                          ;        1  1 
  777.   fmpy   d0,d4,d2 fsub.s d3,d1                             ;        1  1 
  778.   fmpy.s d5,d7,d3                                          ;        1  1 
  779.   fmpy   d4,d6,d3 fsub.s d3,d2                y:(r1)+,d4.s ;Z1      1  1 
  780.   fmpy.s d4,d7,d2              d2.s,d0.s                   ;        1  1 
  781.                   fsub.s d2,d3 d1.s,d5.s                   ;        1  1 
  782.   move                         d3.s,d6.s                   ;        1  1 
  783.   rts                                                      ;        2  2 
  784.  
  785.  
  786. ; y = -w boundary 
  787.  
  788.  
  789. _clip1_yn 
  790.   move                                        y:(r1),d4.s  ;W1      1  1 
  791.   fmpy.s d1,d4,d3              x:(r1)-,d5.s   d1.s,d7.s    ;Y1      1  1 
  792.                   fadd.s d5,d4 x:(r1),d5.s                 ;X1      1  1 
  793.   fmpy.s d2,d4,d2                                          ;        1  1 
  794.   fmpy   d0,d4,d1 fsub.s d3,d2                             ;        1  1 
  795.   fmpy.s d5,d7,d3                                          ;        1  1 
  796.   fmpy   d4,d6,d3 fsub.s d3,d1                y:(r1)+,d4.s ;Z1      1  1 
  797.   fmpy.s d4,d7,d1              d1.s,d0.s                   ;        1  1 
  798.                   fsub.s d1,d3 d2.s,d5.s                   ;        1  1 
  799.   fneg.s d5                    d3.s,d6.s                   ;        1  1 
  800.   rts                                                      ;        2  2 
  801.  
  802.  
  803. ; Clip at z = w boundary 
  804.  
  805.  
  806. _clip1_zp 
  807.   move                                        y:(r1)-,d4.s ;W1      1  1 
  808.   fmpy.s d2,d4,d3              d2.s,d7.s      y:(r1),d6.s  ;Z1      1  1 
  809.                   fsub.s d6,d4 x:(r1)+,d6.s                ;X1      1  1 
  810.   fmpy.s d1,d4,d1                                          ;        1  1 
  811.   fmpy   d0,d4,d2 fsub.s d3,d1                             ;        1  1 
  812.   fmpy.s d6,d7,d3                                          ;        1  1 
  813.   fmpy   d4,d5,d3 fsub.s d3,d2 x:(r1),d4.s                 ;Y1      1  1 
  814.   fmpy.s d4,d7,d2              d2.s,d0.s                   ;        1  1 
  815.                   fsub.s d2,d3 d1.s,d6.s                   ;        1  1 
  816.   move                         d3.s,d5.s                   ;        1  1 
  817.   rts                                                      ;        2  2 
  818.  
  819.  
  820. ; Clip at z = 0 boundary 
  821.  
  822.  
  823. _clip1_zn 
  824.   move                                        y:(r1)-,d2.s ;W1      1  1 
  825.   fmpy.s d2,d6,d2                             y:(r1),d4.s  ;Z1      1  1 
  826.   fmpy.s d1,d4,d1              x:(r1)+,d7.s                ;X1      1  1 
  827.   fmpy   d0,d4,d2 fsub.s d2,d1                             ;        1  1 
  828.   fmpy.s d6,d7,d0              x:(r1),d7.s                 ;Y1      1  1 
  829.   fmpy   d6,d7,d3 fsub.s d0,d2                             ;        1  1 
  830.   fmpy.s d4,d5,d5              d2.s,d0.s                   ;        1  1 
  831.                   fsub.s d3,d5 n0,d6.s                     ;        1  1 
  832.   rts                                                      ;        2  2 
  833.  
  834.  
  835.  
  836. ;--------------------------------------------------------- 
  837. ; 
  838. ;             Double point clipping routines 
  839. ; 
  840. ;--------------------------------------------------------- 
  841.  
  842.  
  843. ; XOld = WOld boundary 
  844.  
  845.  
  846. _clip2_xop 
  847.   move                         (r1)+n1                     ;        1  1 
  848.   move                                        y:(r1)-,d3.s ;Wn      1  1 
  849.                   fadd.s d3,d5 x:(r1)-,d3.s   d5.s,d0.s    ;Xn      1  1 
  850.                   fsub.s d3,d5                             ;        1  1 
  851.   fseedd d5,d4                                             ;        1  1 
  852.   fmpy.s d5,d4,d5              d9.s,d2.s                   ;        1  1 
  853.   fmpy   d0,d4,d0 fsub.s d5,d2 d2.s,d3.s                   ;        1  1 
  854.   fmpy.s d5,d2,d5              d2.s,d4.s                   ;        1  1 
  855.   fmpy   d0,d4,d0 fsub.s d5,d3                             ;        1  1 
  856.   fmpy.s d0,d3,d0                                          ;        1  1 
  857.   fcmp   d7,d0                                             ;        1  1 
  858.   ftfr.s d0,d7    ffgt                                     ;        1  1 
  859.   rts                                                      ;        2  2 
  860.  
  861.  
  862. ; XOld = -WOld boundary 
  863.  
  864.  
  865. _clip2_xon 
  866.   move                         (r1)-                       ;        1  1 
  867.   move                                        y:(r1)-,d3.s ;Wn      1  1 
  868.                   fsub.s d3,d6 x:(r1)+n1,d3.s d6.s,d0.s    ;Xn      1  1 
  869.                   fsub.s d3,d6                             ;        1  1 
  870.   fseedd d6,d4                                             ;        1  1 
  871.   fmpy.s d6,d4,d6              d9.s,d2.s                   ;        1  1 
  872.   fmpy   d0,d4,d0 fsub.s d6,d2 d2.s,d3.s                   ;        1  1 
  873.   fmpy.s d6,d2,d6              d2.s,d4.s                   ;        1  1 
  874.   fmpy   d0,d4,d0 fsub.s d6,d3                             ;        1  1 
  875.   fmpy.s d0,d3,d0                                          ;        1  1 
  876.   fcmp   d7,d0                                             ;        1  1 
  877.   ftfr.s d0,d7    ffgt                                     ;        1  1 
  878.   rts                                                      ;        2  2 
  879.  
  880.  
  881. ; YOld = WOld boundary 
  882.  
  883.  
  884. _clip2_yop 
  885.   move                         (r1)-                       ;        1  1 
  886.   move                                        y:(r1),d3.s  ;Wn      1  1 
  887.                   fadd.s d3,d5 x:(r1)+,d3.s   d5.s,d0.s    ;Yn      1  1 
  888.                   fsub.s d3,d5                             ;        1  1 
  889.   fseedd d5,d4                                             ;        1  1 
  890.   fmpy.s d5,d4,d5              d9.s,d2.s                   ;        1  1 
  891.   fmpy   d0,d4,d0 fsub.s d5,d2 d2.s,d3.s                   ;        1  1 
  892.   fmpy.s d5,d2,d5              d2.s,d4.s                   ;        1  1 
  893.   fmpy   d0,d4,d0 fsub.s d5,d3                             ;        1  1 
  894.   fmpy.s d0,d3,d0                                          ;        1  1 
  895.   fcmp   d7,d0                                             ;        1  1 
  896.   ftfr.s d0,d7    ffgt                                     ;        1  1 
  897.   rts                                                      ;        2  2 
  898.  
  899.  
  900. ; YOld = -WOld boundary 
  901.  
  902.  
  903. _clip2_yon 
  904.   move                         (r1)+                       ;        1  1 
  905.   move                                        y:(r1),d3.s  ;Wn      1  1 
  906.                   fsub.s d3,d6 x:(r1)-,d3.s   d6.s,d0.s    ;Yn      1  1 
  907.                   fsub.s d3,d6                             ;        1  1 
  908.   fseedd d6,d4                                             ;        1  1 
  909.   fmpy.s d6,d4,d6              d9.s,d2.s                   ;        1  1 
  910.   fmpy   d0,d4,d0 fsub.s d6,d2 d2.s,d3.s                   ;        1  1 
  911.   fmpy.s d6,d2,d6              d2.s,d4.s                   ;        1  1 
  912.   fmpy   d0,d4,d0 fsub.s d6,d3                             ;        1  1 
  913.   fmpy.s d0,d3,d0                                          ;        1  1 
  914.   fcmp   d7,d0                                             ;        1  1 
  915.   ftfr.s d0,d7    ffgt                                     ;        1  1 
  916.   rts                                                      ;        2  2 
  917.  
  918.  
  919.  
  920. ; ZOld = WOld boundary 
  921.  
  922. _clip2_zop 
  923.   move                         (r1)+                       ;        1  1 
  924.   move                                        y:(r1)-,d3.s ;Wn      1  1 
  925.                   fadd.s d3,d5 d5.s,d0.s      y:(r1),d3.s  ;Zn      1  1 
  926.                   fsub.s d3,d5                             ;        1  1 
  927.   fseedd d5,d4                                             ;        1  1 
  928.   fmpy.s d5,d4,d5              d9.s,d2.s                   ;        1  1 
  929.   fmpy   d0,d4,d0 fsub.s d5,d2 d2.s,d3.s                   ;        1  1 
  930.   fmpy.s d5,d2,d5              d2.s,d4.s                   ;        1  1 
  931.   fmpy   d0,d4,d0 fsub.s d5,d3                             ;        1  1 
  932.   fmpy.s d0,d3,d0                                          ;        1  1 
  933.   fcmp   d7,d0                                             ;        1  1 
  934.   ftfr.s d0,d7    ffgt                                     ;        1  1 
  935.   rts                                                      ;        2  2 
  936.  
  937.  
  938. ; ZOld = 0 boundary 
  939.  
  940. _clip2_zon 
  941.   move                         (r1)-                       ;        1  1 
  942.   move                                        y:(r1)+,d3.s ;Zn      1  1 
  943.                   fsub.s d3,d6 d6.s,d0.s                   ;        1  1 
  944.   fseedd d6,d4                                             ;        1  1 
  945.   fmpy.s d6,d4,d6              d9.s,d2.s                   ;        1  1 
  946.   fmpy   d0,d4,d0 fsub.s d6,d2 d2.s,d3.s                   ;        1  1 
  947.   fmpy.s d6,d2,d6              d2.s,d4.s                   ;        1  1 
  948.   fmpy   d0,d4,d0 fsub.s d6,d3                             ;        1  1 
  949.   fmpy.s d0,d3,d0                                          ;        1  1 
  950.   fcmp   d7,d0                                             ;        1  1 
  951.   ftfr.s d0,d7    ffgt                                     ;        1  1 
  952.   rts                                                      ;        2  2 
  953.  
  954.  
  955. ; XNew = WNew boundary 
  956.  
  957. _clip2_xnp 
  958.   move                         (r1)+n1                     ;        1  1 
  959.   move                                        y:(r1)-,d0.s ;Wo      1  1 
  960.   move                         x:(r1)-,d2.s                ;Xo      1  1 
  961.                   fsub.s d2,d0                             ;        1  1 
  962.                   fadd.s d0,d5                             ;        1  1 
  963.   fseedd d5,d4                                             ;        1  1 
  964.   fmpy.s d5,d4,d5              d9.s,d2.s                   ;        1  1 
  965.   fmpy   d0,d4,d0 fsub.s d5,d2 d2.s,d3.s                   ;        1  1 
  966.   fmpy.s d5,d2,d5              d2.s,d4.s                   ;        1  1 
  967.   fmpy   d0,d4,d0 fsub.s d5,d3                             ;        1  1 
  968.   fmpy.s d0,d3,d0                                          ;        1  1 
  969.   fcmp   d7,d0                                             ;        1  1 
  970.   ftfr.s d0,d7    fflt                                     ;        1  1 
  971.   rts                                                      ;        2  2 
  972.  
  973. ; XNew = -WNew boundary 
  974.  
  975. _clip2_xnn 
  976.   move                         (r1)-                       ;        1  1 
  977.   move                                        y:(r1)-,d3.s ;Wo      1  1 
  978.   move                         x:(r1)+n1,d2.s              ;Xo      1  1 
  979.                   fadd.s d3,d2                             ;        1  1 
  980.                   fsub.s d6,d2 d2.s,d0.s                   ;        1  1 
  981.   fseedd d2,d4                                             ;        1  1 
  982.   fmpy.s d2,d4,d6              d9.s,d2.s                   ;        1  1 
  983.   fmpy   d0,d4,d0 fsub.s d6,d2 d2.s,d3.s                   ;        1  1 
  984.   fmpy.s d6,d2,d6              d2.s,d4.s                   ;        1  1 
  985.   fmpy   d0,d4,d0 fsub.s d6,d3                             ;        1  1 
  986.   fmpy.s d0,d3,d0                                          ;        1  1 
  987.   fcmp   d7,d0                                             ;        1  1 
  988.   ftfr.s d0,d7    fflt                                     ;        1  1 
  989.   rts                                                      ;        2  2 
  990.  
  991.  
  992. ; YNew = WNew boundary 
  993.  
  994. _clip2_ynp 
  995.   move                         (r1)-                       ;        1  1 
  996.   move                         x:(r1)+,d2.s   y:,d0.s      ;Yo  Wo  1  1 
  997.                   fsub.s d2,d0                             ;        1  1 
  998.                   fadd.s d0,d5                             ;        1  1 
  999.   fseedd d5,d4                                             ;        1  1 
  1000.   fmpy.s d5,d4,d5              d9.s,d2.s                   ;        1  1 
  1001.   fmpy   d0,d4,d0 fsub.s d5,d2 d2.s,d3.s                   ;        1  1 
  1002.   fmpy.s d5,d2,d5              d2.s,d4.s                   ;        1  1 
  1003.   fmpy   d0,d4,d0 fsub.s d5,d3                             ;        1  1 
  1004.   fmpy.s d0,d3,d0                                          ;        1  1 
  1005.   fcmp   d7,d0                                             ;        1  1 
  1006.   ftfr.s d0,d7    fflt                                     ;        1  1 
  1007.   rts                                                      ;        2  2 
  1008.  
  1009.  
  1010. ; YNew = -WNew boundary 
  1011.  
  1012. _clip2_ynn 
  1013.   move                         (r1)+                       ;        1  1 
  1014.   move                         x:(r1)-,d2.s   y:,d3.s      ;Yo  Wo  1  1 
  1015.                   fadd.s d3,d2                             ;        1  1 
  1016.                   fsub.s d6,d2 d2.s,d0.s                   ;        1  1 
  1017.   fseedd d2,d4                                             ;        1  1 
  1018.   fmpy.s d2,d4,d6              d9.s,d2.s                   ;        1  1 
  1019.   fmpy   d0,d4,d0 fsub.s d6,d2 d2.s,d3.s                   ;        1  1 
  1020.   fmpy.s d6,d2,d6              d2.s,d4.s                   ;        1  1 
  1021.   fmpy   d0,d4,d0 fsub.s d6,d3                             ;        1  1 
  1022.   fmpy.s d0,d3,d0                                          ;        1  1 
  1023.   fcmp   d7,d0                                             ;        1  1 
  1024.   ftfr.s d0,d7    fflt                                     ;        1  1 
  1025.   rts                                                      ;        2  2 
  1026.  
  1027. ; ZNew = WNew boundary 
  1028.  
  1029.  
  1030. _clip2_znp 
  1031.   move                         (r1)+                       ;        1  1 
  1032.   move                                        y:(r1)-,d0.s ;Wo      1  1 
  1033.   move                                        y:(r1),d2.s  ;Zo      1  1 
  1034.                   fsub.s d2,d0                             ;        1  1 
  1035.                   fadd.s d0,d5                             ;        1  1 
  1036.   fseedd d5,d4                                             ;        1  1 
  1037.   fmpy.s d5,d4,d5              d9.s,d2.s                   ;        1  1 
  1038.   fmpy   d0,d4,d0 fsub.s d5,d2 d2.s,d3.s                   ;        1  1 
  1039.   fmpy.s d5,d2,d5              d2.s,d4.s                   ;        1  1 
  1040.   fmpy   d0,d4,d0 fsub.s d5,d3                             ;        1  1 
  1041.   fmpy.s d0,d3,d0                                          ;        1  1 
  1042.   fcmp   d7,d0                                             ;        1  1 
  1043.   ftfr.s d0,d7    fflt                                     ;        1  1 
  1044.   rts                                                      ;        2  2 
  1045.  
  1046.  
  1047. ; ZNew = 0 boundary 
  1048.  
  1049.  
  1050. _clip2_znn 
  1051.   move                         d6.s,d0.s      y:(r1),d6.s  ;Zo      1  1 
  1052.                   fsub.s d0,d6 d6.s,d0.s                   ;        1  1 
  1053.   fseedd d6,d4                                             ;        1  1 
  1054.   fmpy.s d6,d4,d6              d9.s,d2.s                   ;        1  1 
  1055.   fmpy   d0,d4,d0 fsub.s d6,d2 d2.s,d3.s                   ;        1  1 
  1056.   fmpy.s d6,d2,d6              d2.s,d4.s                   ;        1  1 
  1057.   fmpy   d0,d4,d0 fsub.s d6,d3                             ;        1  1 
  1058.   fmpy.s d0,d3,d0                                          ;        1  1 
  1059.   fcmp   d7,d0                                             ;        1  1 
  1060.   ftfr.s d0,d7    fflt                                     ;        1  1 
  1061.   rts                                                      ;        2  2 
  1062.